transegb

transegb — Construit une enveloppe définie par l'utilisateur en temps absolu.

Description

Construit une enveloppe définie par l'utilisateur en temps absolu.

Syntaxe

ares transegb ia, itim, itype, ib [, itim2] [, itype] [, ic] ...
kres transegb ia, itim, itype, ib [, itim2] [, itype] [, ic] ...

Initialisation

ia -- valeur initiale.

ib, ic, etc. -- valeur après itim secondes.

itim -- date en secondes de la fin du premier segment.

itim2,... itimx etc. -- date en secondes de la fin des segments suivants.

itype, itype2, etc. -- si 0, un segment de droite est généré. Si différent de 0, transegb crée la courbe suivante sur n pas :


ibeg + (ivalue - ibeg) * (1 - exp( i*itype/(n-1) )) / (1 - exp(itype))
      

Exécution

Si itype > 0, on a une courbe montant lentement (concave) ou décroissant lentement (convexe), tandis que si itype < 0, la courbe monte rapidement (convexe) ou décroit rapidement (concave). Voir aussi GEN16.

Exemples

Voici un exemple de l'opcode transegb. Il utilise le fichier transegb.csd. L'exemple produit la sortie suivante :

Sortie de l'exemple de transegb.

Sortie de l'exemple de transegb.

Exemple 915. Exemple de l'opcode transegb.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc    ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o transeg.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 128
nchnls = 2

0dbfs = 1

instr 1
;p4 and p5 determine the type of curve for each
;section of the envelope
kenv transegb 0.01, p3*0.25, p4, 1, p3, p5, 0.01
a1 oscil kenv, 440, 1
outs a1, a1
endin

</CsInstruments>
<CsScore>
; Table #1, a sine wave.
f 1 0 16384 10 1

i 1 0 2 2 2
i 1 + . 5 5
i 1 + . 1 1
i 1 + . 0 0
i 1 + . -2 -2
i 1 + . -2 2
i 1 + . 2 -2
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

expseg, expsega, expsega, expsegr, linseg, linsegb, linsegr, transeg transegr

Crédits

Auteur : John ffitch
Université de Bath, Codemist. Ltd.
Bath, UK
Juin 2011

Nouveau dans la version 5.14 de Csound.