sfinstr3m

sfinstr3m — Joue un instrument échantillonné SoundFont2 (SF2), produisant un son mono avec interpolation cubique.

Description

Joue un instrument échantillonné SoundFont2 (SF2), produisant un son mono avec interpolation cubique. Ces opcodes permettent la gestion de la structure d'échantillon des fichiers SF2. Afin de comprendre l'utilisation de ces opcodes, il faut connaître le format SF2 dont on peut trouver une brève description dans l'annexe Format de Fichier SoundFont2.

Syntaxe

ares sfinstr3m ivel, inotenum, xamp, xfreq, instrnum, ifilhandle \
      [, iflag] [, ioffset]

Initialisation

ivel -- vélocité.

inotenum -- numéro de note MIDI.

instrnum -- numéro d'un instrument d'un fichier SF2.

ifilhandle -- nombre unique généré par l'opcode sfload à utiliser comme identificateur pour un fichier SF2. On peut charger et activer plusieurs fichiers SF2 en même temps.

iflag (facultatif) -- drapeau concernant le comportement de xfreq et de inotenum.

ioffset (facultatif) -- endroit où commence la lecture, en échantillons.

Exécution

xamp -- facteur de correction de l'amplitude.

xfreq -- valeur de fréquence ou multiplicateur de fréquence, selon la valeur de iflag. Quand iflag = 0, xfreq est un multiplicateur de la fréquence par défaut, fixée par le preset SF2 à la valeur inotenum. Quand iflag = 1, xfreq est la fréquence absolue du son produit, en Hz. La valeur par défaut est 0.

Lorsque iflag = 0, inotenum fixe la fréquence de la sortie en fonction du numéro de note MIDI utilisé, et xfreq est utilisé comme un multiplicateur. Lorsque iflag = 1, la fréquence de la sortie est fixée directement par xfreq. Cela permet l'utilisation de n'importe quelle échelle micro-tonale. Cependant, cette méthode n'est conçue pour travailler correctement qu'avec des presets accordés selon le classique tempérament égal. L'utilisation de cette méthode avec un preset ayant déjà un accordage non standard ou bien avec des presets de drum-kit donnera des résultats imprévisibles.

L'amplitude peut être ajustée en variant l'argument xamp qui agit comme un multiplicateur.

Le paramètre ioffset permet de commencer la lecture depuis un autre échantillon que le premier. L'utilisateur doit s'assurer que sa valeur est inférieure à la longueur du son. Sinon, il y a un risque de plantage de Csound.

sfinstr3m est une version avec interpolation cubique de sfinstrm. La différence de qualité sonore est notable, particulièrement avec les échantillons transposés dans le grave. Pour les échantillons transposés dans l'aigu, la différences est moins appréciable et je suggère d'utiliser les versions avec interpolation linéaire, car elles sont plus rapides.

Ces opcodes ne supportent que la structure d'échantillon des fichiers SF2. La structure de modulateur du format SoundFormat2 n'est pas supportée dans Csound. Tout traitement ou modulation des données échantillonnées est à la charge de l'utilisateur de Csound, ce qui permet de s'affranchir de toutes les restrictions imposées par le standard SF2.

Exemples

Voici un exemple de l'opcode sfinstr3m. Il utilise le fichier sfinstr3m.csd.

Exemple 781. Exemple de l'opcode sfinstr3m.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac -+rtmidi=virtual -M0 ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sfinstr3m.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100 
ksmps = 32
nchnls = 2
0dbfs  = 1 


gisf	sfload	"07AcousticGuitar.sf2"
	sfilist	isf

instr 1	; play from score and midi keyboard

	mididefault	60, p3
	midinoteonkey	p4, p5
inum	init	p4
ivel	init	p5
ivel	init	ivel/127					;make velocity dependent
kamp	linsegr	1, 1, 1, .1, 0
kamp	= kamp/7000						;scale amplitude
kfreq	init	1						;do not change freq from sf
aout	sfinstr3m ivel, inum, kamp*ivel, kfreq, 0, gisf
	outs	aout, aout
	
	endin
	
</CsInstruments>
<CsScore>
f0  60				; stay active for 1 minute

i1 0 1 60 127
i1 + 1 62 <
i1 + 1 65 <
i1 + 1 69 10

e
</CsScore>
</CsoundSynthesizer>


Voir aussi

sfilist, sfinstr3, sfinstr, sfinstrm, sfload, sfpassign, sfplay3, sfplay3m, sfplay, sfplaym, sfplist, sfpreset

Crédits

Auteur : Gabriel Maldonado
Italie
Mai 2000

Nouveau dans la version 4.07 de Csound