outkat

outkat — Envoie des messages MIDI aftertouch au taux-k.

Description

Envoie des messages MIDI aftertouch au taux-k.

Syntaxe

outkat kchn, kvalue, kmin, kmax

Exécution

kchn -- numéro de canal MIDI (1-16)

kvalue -- valeur en virgule flottante

kmin -- valeur minimale en virgule flottante (convertie en valeur entière MIDI 0)

kmax -- valeur maximale en virgule flottante (convertie en valeur entière MIDI 127)

outkat envoie des messages aftertouch au taux-k. Il ne fonctionne qu'avec les instruments MIDI qui les reconnaissent. Il peut piloter une valeur différente de paramètre pour chaque note active.

Il peut échelonner un argument de taux-k en virgule flottante selon les valeurs kmin et kmax. Par exemple avec kmin = 1.0 et kmax = 2.0, lorque l'argument kvalue reçoit la valeur 2.0, l'opcode envoie la valeur 127 sur le périphérique MIDI OUT. Lorsque l'argument kvalue reçoit la valeur 1.0, il envoie la valeur 0. Les opcodes de taux-k envoient un message chaque fois que la valeur MIDI traduite de l'argument kvalue change.

Exemples

Voici un exemple de l'opcode outkat. Il utilise le fichier outkat.csd.

Exemple 560. Exemple de l'opcode outkat.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac -Q1 -M0  ;;;realtime audio out and midi in and out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o outkat.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 10
nchnls = 2

instr 1

ikey notnum 
ivel  veloc

kvib linseg 100, .5, 120	;vary aftertouch in .5 second
kvbr = int(kvib)		;whole numbers only
outkat 1, kvbr, 0, 127		;assign aftertouch on
printk2 kvbr			;external synth for example to
midion 1, ikey, ivel		;change depth of filter modulation

endin
</CsInstruments>
<CsScore>
f0 30 				;play for 30 seconds

e
</CsScore>
</CsoundSynthesizer>


Voir aussi

outiat, outic14, outic, outipat, outipb, outipc, outkc14, outkc, outkpat, outkpb, outkpc

Crédits

Auteur : Gabriel Maldonado
Italie

Nouveau dans la version 3.47 de Csound.

Merci à Rasmus Ekman pour avoir indiqué les intervalles corrects pour le canal MIDI et les numéros de contrôleur.