multitap

multitap — Ligne à retard avec plusieurs points de lecture.

Description

Ligne à retard avec plusieurs points de lecture.

Syntaxe

ares multitap asig [, itime1, igain1] [, itime2, igain2] [...]

Initialisation

Les arguments itime et igain fixent la position et le gain de chaque point de lecture.

La ligne à retard est remplie par asig.

Exemples

Voici un exemple de l'opcode multitap. Il utilise le fichier multitap.csd

Exemple 516. Exemple de l'opcode multitap.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o multitap.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

ga1 init 0

instr 1

asig diskin2 "beats.wav", 1,0
     outs asig, asig
   
ga1  = ga1+asig
endin

instr 2

asig multitap ga1, 1.2, .5, 1.4, .2
     outs     asig, asig
	
ga1  = 0
endin

</CsInstruments>
<CsScore>

i 1 .5 .2	; short sound
i 2  0  3	; echoes
e
</CsScore>
</CsoundSynthesizer>


Cela produit deux délais, l'un de longueur 1.2 et de gain 0.5, et l'autre de longueur 1.4 et de gain 0.2

Crédits

Auteur : Paris Smaragdis
MIT, Cambridge
1996