max

max — Produit un signal qui est le maximum de tous les signaux d'entrée.

Description

L'opcode max prend en entrée n'importe quel nombre de signaux de taux-a ou de taux-k (tous au même taux), et retourne un signal du même taux qui est le maximum de toutes les entrées. Pour les signaux de taux-a, les entrées sont comparées échantillon par échantillon (c-à-d que max n'examine pas une période ksmps entière du signal pour trouver son maximum local comme l'opcode max_k le fait).

Syntaxe

amax max ain1, ain2 [, ain3] [, ain4] [...]
kmax max kin1, kin2 [, kin3] [, kin4] [...]

Exécution

ain1, ain2, ... -- signaux de taux-a à comparer.

kin1, kin2, ... -- signaux de taux-k à comparer.

Exemples

Voici un exemple de l'opcode max. Il utilise le fichier max.csd.

Exemple 457. Exemple de l'opcode max.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o max.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

k1   oscili 1, 10.0, 1			;combine 3 sinusses
k2   oscili 1, 1.0, 1			;at different rates
k3   oscili 1, 3.0, 1
kmax max   k1, k2, k3
kmax = kmax*250				;scale kmax
printk2 kmax				;check the values

aout vco2 .5, 220, 6			;sawtooth
asig moogvcf2 aout, 600+kmax, .5 	;change filter around 600 Hz		
     outs asig, asig

endin

</CsInstruments>
<CsScore>
f1 0 32768 10 1

i1 0 5
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

min, maxabs, minabs, maxaccum, minaccum, maxabsaccum, minabsaccum, max_k

Crédits

Auteur : Anthony Kozar
Mars 2006

Nouveau dans la version 5.01 de Csound.