filevalid

filevalid
Précédent	Opcodes et opérateurs de l'orchestre	Suivant

Description

Retourne 1 si le fichier son est valide, 0 sinon.

Syntaxe

ir filevalid ifilcod

Initialisation

ifilcod -- fichier son à tester

Exécution

filevalid retourne 1 si le fichier son ifilcod peut être utilisé.

Exemples

Voici un exemple de l'opcode filevalid. Il utilise le fichier filevalid.csd.

Exemple 242. Exemple de l'opcode filevalid.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o filevalid.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1
Sfile     strget    p4
ivld      filevalid Sfile

if ivld>0 then
asig      diskin2   Sfile, 1
          outs      asig, asig
else
          printf_i  "Audiofile '%s' does not exist!\n", 1, Sfile
endif
endin

</CsInstruments>
<CsScore>

i 1 0 3 "frox.wav";file does not exist!!!
i 1 + 3 "fox.wav" ;but this one certainly does...

e
</CsScore>
</CsoundSynthesizer>

Sa sortie contiendra une ligne comme celle-ci :

Audiofile 'frox.wav' does not exist!

Voir aussi

filebit, filelen, filenchnls, filepeak, filesr

Crédits

Auteur : Matt Ingalls

Juillet 2010

Nouveau dans la version 5.13