dispfft

displayfft — Affiche la transformée de Fourier d'un signal audio ou de contrôle.

Description

Ces unités affichent les valeurs d'initialisation de l'orchestre ou produisent un affichage graphique de signaux de contrôle ou audio de l'orchestre. Des fenêtres X11 sont utilisées s'il est activé, sinon (ou si l'option -g est positionnée) on a un affichage approximatif en caractères ASCII.

Syntaxe

dispfft xsig, iprd, iwsiz [, iwtyp] [, idbout] [, iwtflg]

Initialisation

iprd -- la période d'affichage en secondes.

iwsiz -- taille de la fenêtre d'entrée en échantillons. Une fenêtre de iwsiz points produira une transformée de Fourier de iwsiz/2 points, répartis linéairement en fréquence de 0 à sr/2. iwsiz doit être une puissance de 2, comprise entre 16 et 4096. Les fenêtres peuvent se chevaucher.

iwtyp (facultatif, 0 par défaut) -- type de fenêtre. 0 = rectangulaire, 1 = Hanning. La valeur par défaut est 0 (rectangulaire).

idbout (facultatif, 0 par défaut) -- unité d'affichage des coefficients de Fourier. 0 = magnitude, 1 = décibels. La valeur par défaut est 0 (magnitude).

iwtflg (facultatif, 0 par défaut) -- indicateur de maintien. S'il est différent de zéro, chaque affichage est maintenu jusqu'à ce que l'utilisateur le libère. La valeur par défaut est 0 (pas de maintien).

Exécution

dispfft -- affiche la transformée de Fourier d'un signal audio ou de contrôle (asig ou ksig) chaque iprd secondes au moyen de la méthode de transformée de Fourier rapide.

Exemples

Voici un exemple de l'opcode dispfft. Il utilise le fichier dispfft.csd.

Exemple 187. Exemple de l'opcode dispfft.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o dispfft.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1

kcps = 110
ifn  = 1

knh	line p4, p3, p5
asig	buzz 1, kcps, knh, ifn
	outs asig, asig

dispfft	asig, .1, 2048, 0, 1

endin
</CsInstruments>
<CsScore>
;sine wave.
f 1 0 16384 10 1

i 1 0 3 20 20
i 1 + 3 3 3
i 1 + 3 150 1
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

display, print