tlineto

tlineto — Generate glissandos starting from a control signal.

Description

Generate glissandos starting from a control signal with a trigger.

Syntax

kres tlineto ksig, ktime, ktrig

Performance

kres -- Output signal.

ksig -- Input signal.

ktime -- Time length of glissando in seconds.

ktrig -- Trigger signal.

tlineto is similar to lineto but can be applied to any kind of signal (not only stepped signals) without producing discontinuities. Last value of each segment is sampled and held from input signal each time ktrig value is set to a nonzero value. Normally ktrig signal consists of a sequence of zeroes (see trigger opcode).

The effect of glissando is quite different from port. Since in these cases, the lines are straight. Also the context of usage is different.

Examples

Here is an example of the tlineto opcode. It uses the file tlineto.csd.

Example 908. Example of the tlineto opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o tlineto.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

giSine ftgen 0, 0, 2^10, 10, 1

instr 1


kmtr lfo 1, .5, 1			;produce trigger signal			
ktr  trigger kmtr, .5, 0		;with triangle wave

ktime = p4				
kfreq randh 1000, 3, .2, 0, 500		;generate random values
kfreq tlineto kfreq, ktime, ktr		;different glissando times
aout  poscil .4, kfreq, giSine
      outs aout, aout

endin
</CsInstruments>
<CsScore>

i 1 0 10 .2	;short glissando
i 1 11 10 .8	;longer glissande
e
</CsScore>
</CsoundSynthesizer>


See Also

lineto

Credits

Author: Gabriel Maldonado

New in Version 4.13