midipolyaftertouch

midipolyaftertouch — Gets a MIDI polyphonic aftertouch value.

Description

midipolyaftertouch is designed to simplify writing instruments that can be used interchangeably for either score or MIDI input, and to make it easier to adapt instruments originally written for score input to work with MIDI input.

In general, it should be possible to write instrument definitions that work identically with both scores and MIDI, including both MIDI files and real-time MIDI input, without using any conditional statements, and that take full advantage of MIDI voice messages.

Note that correlating Csound instruments with MIDI channel numbers is done using the massign opcode for real-time performance,. For file-driven performance, instrument numbers default to MIDI channel number + 1, but the defaults are overridden by any MIDI program change messages in the file.

Syntax

midipolyaftertouch xpolyaftertouch, xcontrollervalue [, ilow] [, ihigh]

Initialization

ilow (optional) -- optional low value after rescaling, defaults to 0.

ihigh (optional) -- optional high value after rescaling, defaults to 127.

Performance

xpolyaftertouch -- returns MIDI polyphonic aftertouch during MIDI activation, remains unchanged otherwise.

xcontrollervalue -- returns the value of the MIDI controller during MIDI activation, remains unchanged otherwise.

If the instrument was activated by MIDI input, the opcode overwrites the values of xpolyaftertouch and xcontrollervalue with the corresponding values from MIDI input. If the instrument was NOT activated by MIDI input, the values of xpolyaftertouch and xcontrollervalue remain unchanged.

This enables score p-fields to receive MIDI input data during MIDI activation, and score values otherwise.

[Note] Adapting a score-activated Csound instrument.

See the MIDI interop opcodes section for details on adapting score driven instruments for MIDI or vice-versa.

Examples

Here is an example of the midipolyaftertouch opcode. It uses the file midipolyaftertouch.csd.

Example 488. Example of the midipolyaftertouch opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    -M1  ;;;realtime audio out and midi in 
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o midipolyaftertouch.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1;midi keyboard and score are used

midinoteoncps p4, p5				;puts MIDI key translated to cycles per second into p4, and MIDI velocity into p5

kafter  init 127				;full open				
midipolyaftertouch  kafter, 1
printk2 kafter					;display the key value when it changes and when key is pressed
 
kvel = p5/127					;scale midi velocity to 0-1
kenv madsr 0.5, 0.8, 0.8, 0.5			;amplitude envelope multiplied by
ain  pluck kenv*kvel, p4, p4, 2, 1		;velocity value			
asig moogvcf2 ain, 300+(kafter*100), .5		;use value of aftertouch to control frequency of filter
     outs  asig, asig				;base freq of filter = 300 Hz

endin
</CsInstruments>
<CsScore>
f 0 30	;runs for 30 seconds
f 2 0 4096 10 1	;sine wave

i 1 0 2 440 100	;play these notes from score as well
i 1 + 2 1440 100
e

</CsScore>
</CsoundSynthesizer>


Its output should include lines like:

 i1   127.00000
 i1    20.00000
 i1    44.00000
      

See Also

midichannelaftertouch, midicontrolchange, mididefault, midinoteoff, midinoteoncps, midinoteonkey, midinoteonoct, midinoteonpch, midipitchbend, midiprogramchange

Credits

Author: Michael Gogins

New in version 4.20