ins

ins — Reads stereo audio data from an external device or stream.

Description

Reads stereo audio data from an external device or stream.

[Warning] Warning

This opcode is designed to be used only with orchestras that have nchnls_i=2. Doing so with orchestras with nchnls_i > 2 will cause incorrect audio input.

Syntax

ar1, ar2 ins

Performance

Reads stereo audio data from an external device or stream. If the command-line -i flag is set, sound is read continuously from the audio input stream (e.g. stdin or a soundfile) into an internal buffer. Any number of these opcodes can read freely from this buffer.

Examples

Here is an example of the ins opcode. It uses the file ins.csd.

Example 385. Example of the ins opcode.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   -idac   ;;;realtime audio I/O
; For Non-realtime ouput leave only the line below:
; ins.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2				;two channels out
0dbfs  = 1

instr 1 

ain1, ainr ins				;grab your mic and sing
adel  linseg 0, p3*.5, 0.02, p3*.5, 0	;max delay time = 20ms
aoutl flanger ain1, adel, .7
aoutr flanger ain1, adel*2, .8
      fout "in_s.wav", 14, aoutl, aoutr ;write to stereo file,
      outs aoutl, aoutr			;16 bits with header

endin
</CsInstruments>
<CsScore>

i 1 0 10
e
</CsScore>
</CsoundSynthesizer>


See Also

diskin, in, inh, inh, ino, inq, soundin mp3in,

Credits

Authors: Barry L. Vercoe, Matt Ingalls/Mike Berry
MIT, Mills College
1993-1997