atonek

atonek — A hi-pass filter whose transfer functions are the complements of the tonek opcode.

Description

A hi-pass filter whose transfer functions are the complements of the tonek opcode.

Syntax

kres atonek ksig, khp [, iskip]

Initialization

iskip (optional, default=0) -- initial disposition of internal data space. Since filtering incorporates a feedback loop of previous output, the initial status of the storage space used is significant. A zero value will clear the space; a non-zero value will allow previous information to remain. The default value is 0.

Performance

kres -- the output signal at control-rate.

ksig -- the input signal at control-rate.

khp -- the response curve's half-power point, in Hertz. Half power is defined as peak power / root 2.

atonek is a filter whose transfer functions is the complement of tonek. atonek is thus a form of high-pass filter whose transfer functions represent the filtered out aspects of their complements. However, power scaling is not normalized in atonek but remains the true complement of the corresponding unit.

Examples

Here is an example of the atonek opcode. It uses the file atonek.csd.

Example 56. Example of the atonek opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o atonek.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>
sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

gisin ftgen 0, 0, 2^10, 10, 1

instr 1

ksig	randomh	400, 1800, 150
aout	poscil	.2, 1000+ksig, gisin
	outs	aout, aout
endin

instr 2

ksig	randomh	400, 1800, 150
khp	line	1, p3, 400	;vary high-pass
ksig	atonek	ksig, khp
aout	poscil	.2, 1000+ksig, gisin
	outs	aout, aout
endin

</CsInstruments>
<CsScore>
i 1 0 5
i 2 5.5 5
e
</CsScore>
</CsoundSynthesizer>


See Also

areson, aresonk, atone, port, portk, reson, resonk, tone, tonek

Credits

Author: Robin Whittle
Australia
May 1997