ATSinterpread

ATSinterpread — allows a user to determine the frequency envelope of any ATSbufread.

Description

ATSinterpread allows a user to determine the frequency envelope of any ATSbufread.

Syntax

kamp ATSinterpread kfreq

Performance

kfreq - a frequency value (given in Hertz) used by ATSinterpread as in index into the table produced by an ATSbufread.

ATSinterpread takes a frequency value (kfreq in Hz). This frequency is used to index the data of an ATSbufread. The return value is an amplitude gained from the ATSbufread after interpolation. ATSinterpread allows a user to determine the frequency envelope of any ATSbufread. This data could be useful for an number of reasons, one might be performing cross synthesis of data from an ATS file and non ATS data.

Examples

Here is an example of the ATSinterpread opcode. It uses the file ATSinterpread.csd.

Example 67. Example of the ATSinterpread opcode.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc for RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o ATSinterpread.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1	; "beats.ats" is created by atsa

ktime	line	0, p3, 1.8
	ATSbufread ktime, 1, "beats.ats", 42
kamp	ATSinterpread 	p4
aosc	oscili	kamp, p4, 1
	outs	aosc * 25, aosc *25

endin

</CsInstruments>
<CsScore>
; sine wave.
f 1 0 16384 10 1

i 1 0 2 100
e

</CsScore>
</CsoundSynthesizer>


This example shows how to use ATSinterpread. Here a frequency is given by the score (p4) and this frequency is given to an ATSinterpread (with a corresponding ATSbufread). The ATSinterpread uses this frequency to output a corresponding amplitude value, based on the atsfile given by the ATSbufread (beats.ats in this case). We then use that amplitude to scale a sine-wave that is synthesized with the same frequency (p4). You could extend this to include multiple sine-waves. This way you could synthesize any reasonable frequency (within the low and high frequencies of the indicated ATS file), and maintain the shape (in frequency) of the indicated atsfile (given by the ATSbufread).

See also

ATSread, ATSreadnz, ATSinfo, ATSsinnoi, ATSbufread, ATScross, ATSpartialtap, ATSadd, ATSaddnz

Credits

Author: Alex Norman
Seattle,Washington
2004